10 CLS
20 PRINT "PLOT OF FUNCTIONS" 
30 PRINT 
40 DIM Y(9),A$(11) 
50 FOR I=1 TO 11 
60 READ A$(I)
70 NEXT I 
80 PRINT "NUMBER OF FUNCTIONS TO BE PLOTTED"; 
90 INPUT N
100 PRINT "X-AXIS:LEFT ENDPOINT, RIGHT ENDPOINT, INCREMENT"; 
110 INPUT X1,X2,X3
120 PRINT "Y-AXIS:LOWER ENDPOINT, UPPER ENDPOINT, INCREMENT"; 
130 INPUT Y1,Y2,Y3
140 Y2=(Y2-Y1)/Y3
150 IF Y2<=62 THEN 180  
160 PRINT "Y-RANGE TOO LARGE" 
170 GOTO 120  
180 PRINT 
190 PRINT 
200 PRINT "X-AXIS CROSSES Y-AXIS AT Y=";Y1
210 PRINT "Y-AXIS CROSSES X-AXIS AT X=";X1 
220 PRINT 
230 FOR X=X1 TO X2 STEP X3
240 REM - ENTER FUNCTIONS Y(1) TO Y(N) (MAXIMUM OF 9 FUNCTIONS)           AT LINES 241 THROUGH 249.
250 FOR I=1 TO N 
260 Y(I)=INT((Y(I)-Y1)/Y3+.5)
270 NEXT I 
280 FOR I=0 TO Y2 
290 S=0 
300 FOR J=1 TO N 
310 IF Y(J)<>I THEN 340  
320 S=S+1 
330 T=J 
340 NEXT J 
350 IF S>0 THEN 380  
360 PRINT A$(SGN(I)+10); 
370 GOTO 420  
380 IF S>1 THEN 410  
390 PRINT A$(T); 
400 GOTO 420  
410 PRINT "*"; 
420 NEXT I 
430 IF X>X1 THEN 450  
440 PRINT "Y"; 
450 PRINT 
460 A$(11)=" "
470 NEXT X 
480 PRINT "X"
490 DATA "1","2","3","4","5","6","7","8","9","+","+"
500 END