10 CLS
20 PRINT "CHECK WRITER" 
30 PRINT 
40 DIM M1$(40)
50 DATA "ONE","TWO","THREE","FOUR","FIVE","SIX"
60 DATA "SEVEN","EIGHT","NINE","TEN","ELEVEN","TWELVE"
70 DATA "THIRTEEN","FOURTEEN","FIFTEEN","SIXTEEN"
80 DATA "SEVENTEEN","EIGHTEEN","NINETEEN","TWENTY","THIRTY"
90 DATA "FORTY","FIFTY","SIXTY","SEVENTY","EIGHTY","NINETY"
100 DATA "JANUARY","FEBRUARY","MARCH","APRIL"
110 DATA "MAY","JUNE","JULY","AUGUST"
120 DATA "SEPTEMBER","OCTOBER","NOVEMBER","DECEMBER"
130 FOR I=1 TO 39
140 READ M1$(I)
150 NEXT I
160 PRINT "DATE (MMDDYY)";
170 INPUT D 
180 PRINT "--(TO END PROGRAM ENTER 'END')--" 
190 PRINT "FIRST NAME OF PAYEE"; 
200 INPUT F$ 
210 IF F$="END" THEN 860  
220 PRINT "LAST NAME OF PAYEE"; 
230 INPUT L$ 
240 PRINT "AMOUNT OF CHECK"; 
250 INPUT A
260 PRINT "READY TO PRINT CHECK"; 
270 INPUT X 
280 D1=INT(D/10000) 
290 D2=INT((D-D1*10000)/100) 
300 D3=INT(D-(D1*100+D2)*100)
310 ITEM=27+D1
320 X0$=M1$(ITEM)
330 PRINT ,,,X0$;D2;"  ";D3 
340 PRINT ,,,"$";A 
350 PRINT ,,," ";A
360 PRINT 
370 PRINT ,F$;" ";L$
380 PRINT 
390 IF A<=0 THEN 840  
400 A=A+.001 : A1=A
410 N1=INT(A1/1E3) 
420 IF N1>99 THEN 840  
430 IF N1=0 THEN 460  
440 GOSUB 710  
450 PRINT "THOUSAND "; 
460 A1=A1-N1*1E3 
470 N1=INT(A1/100) 
480 IF N1=0 THEN 510  
490 GOSUB 710  
500 PRINT "HUNDRED "; 
510 A1=A1-N1*100 
520 N1=INT(A1)
530 IF N1>0 THEN 560  
540 IF A>=1 THEN 570  
550 GOTO 580  
560 GOSUB 710  
570 PRINT "DOLLARS "; 
580 A1=A1-N1
590 IF A1<.01 THEN 670  
600 IF A<1 THEN 620  
610 PRINT "AND"; 
620 A1=A1*100 
630 PRINT INT(A1+.5);"CENTS"
640 PRINT 
650 PRINT 
660 PRINT 
670 PRINT 
680 PRINT 
690 PRINT 
700 GOTO 190  
710 IF N1<21 THEN 800  
720 ITEM=(N1-20)/10+20
730 X0$=M1$(ITEM)
740 PRINT X0$; 
750 A3=N1-INT(N1/10)*10 
760 IF A3=0 THEN 830  
770 PRINT "-"; 
780 ITEM=A3
790 GOTO 810  
800 ITEM=N1
810 X0$=M1$(ITEM)
820 PRINT X0$;" ";
830 RETURN 
840 PRINT ,"*****VOID*****" 
850 GOTO 640  
860 END