100 CLEAR200:DIMA$(60):FORN=1TO59:READA$:A$(N)=A$:NEXT
110 DATA ,,141141,,,,,144441,414414,414414,,,441144,411114,141414,41141
120 DATA 44444,14444,11444,11144,11114,11111,41111,44111,44411,44441,444111,414141,,41114,,114411,,14,4111,4141,411,1,1141,441,1111,11,1444,414,1411,44,41,444,1441,4414,141,111,4,114,1114,144,4114,4144,4411
130 CLS:PRINT@45,"NOVICE":PRINT@74,"CODE  TRAINER":PRINT@106,"FOR THE MC-10":PRINT@202,"1) U-SEE-UM":PRINT@234,"2) GUESS WHO":PRINT@266,"3) TYPE IT"
140 I$=INKEY$:IFI$=""THEN140
150 IFI$="1"THEN190
160 IFI$="2"THEN250
170 IFI$="3"THEN420
180 GOTO140
190 ST=1000:CLS:PRINT@13,"U-SEE-UM":PRINT@64,"CHARACTERS APPEAR ON THE SCREEN":PRINT@142,"PRESS":PRINT@170,"ENTER TO START":PRINT@201," SPACE TO STOP"
200 I$=INKEY$:IFI$=""THEN200
210 IFI$<>CHR$(13)THEN200
220 N=RND(59):IFA$(N)=""THEN220
230 PRINTCHR$(N+31);" ";:I$=INKEY$:IFI$=CHR$(32)THEN RUN
240 GOSUB600:GOTO220
250 ST=500:CLS:PRINT@12,"GUESS WHO":PRINT@96," YOU GET THREE CHANCES TO GUESS      1,2, OR 3 LETTER GROUPS":PRINT@194,"WHAT SIZE DO YOU WANT? 1,2,3"
260 I$=INKEY$:IFI$=""THEN260
270 IFVAL(I$)<1 OR VAL(I$)>3THEN270
280 V=VAL(I$):PRINT@238,"<"V">":PRINT@263,"PRESS SPACE TO STOP"
290 C$="":FORN=1TOV
300 C=RND(59):IFA$(C)=""THEN300
310 C$=C$+CHR$(C+31):NEXTN
320 FORCH=1TO3:PRINT@331,"-- LISTEN --":PRINT@399,"   "
330 FORK=1TOV:N=ASC(MID$(C$,K,1))-31:GOSUB600:NEXTK:PRINT@331,"WHAT WAS IT?":CN=0:Z$=""
340 I$=INKEY$:IFI$="" OR I$=CHR$(13)THEN340
350 IFI$=" "THEN RUN
360 PRINT@399+CN,I$:Z$=Z$+I$:CN=CN+1
370 IFCN<V THEN340
380 IFZ$=C$THENPRINT@331,"** RIGHT! **":FORT=1TO500:NEXTT:GOTO290
390 IFCH<3THENPRINT@329,"NOPE, TRY AGAIN":FORT=1TO500:NEXTT
400 PRINT@329,"":NEXTCH
410 PRINT@329,"SORRY, IT WAS ";C$:FORT=1TO500:NEXTT:PRINT@329,"":GOTO290
420 SP$=CHR$(13)+CHR$(13)+CHR$(13)+CHR$(13):T$="":ST=300:CLS:PRINT@10,"YOU-TYPE-IT":PRINT:PRINT" TYPE IN THE LETTER, GROUP, OR   WORD YOU WANT TO PRACTICE (UP   TO 96  CHARACTERS)  AND PRESS   ENTER TO START AND REPEAT THE   GROUP, SPACE TO STOP. ";
430 PRINT"ENTER A   BLANK TO QUIT."
440 I$=INKEY$:IFI$=""THEN440
450 IFI$=CHR$(13)THEN510
460 IFI$=CHR$(8) AND T$<>""THENT$=LEFT$(T$,LEN(T$)-1):GOTO490
470 IFLEN(T$)<96THEN T$=T$+I$:GOTO490
480 SOUND100,1
490 PRINT@288,T$:PRINT
500 GOTO440
510 IFT$=""THEN RUN
520 PRINT@288,SP$;
530 FORK=1TOLEN(T$):N=ASC(MID$(T$,K,1))-31:IFINKEY$=CHR$(32)THEN550
540 PRINT@288,LEFT$(T$,K):GOSUB600:NEXTK
550 I$=INKEY$:IFI$=""THEN550
560 IFI$=CHR$(13)THEN510
570 IFI$=CHR$(32)THEN420
580 GOTO560
590 STOP
600 FORP=1TOLEN(A$(N)):S=VAL(MID$(A$(N),P,1)):GOSUB610:NEXTP:GOTO 630
610 IFS<>0THEN SOUND160,S:FORT=1TO50:NEXTT
620 RETURN
630 FORT=1TO ST:NEXTT
640 RETURN